home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amiga Tools 3
/
Amiga Tools 3.iso
/
audio
/
audioed
/
audioed286
/
install
< prev
next >
Wrap
Text File
|
1995-08-27
|
6KB
|
262 lines
; $VER: AudioED V 2.86 (27.08.95)
;
; Installation script for the Commodore Installer (tm)
;
; Installs the program AudioED 2.86 by Frank Enderle to your
; harddisk partition.
; startup message
(set old_level @user-level)
(set sys_ver (/ (getversion "exec.library" (resident)) 65536))
(if (< sys_ver 37) (
(abort "AudioED requires at least Kickstart 2.04 !")
(exit (quiet))
))
(user 1)
(message "This script installs the program\n\nAudioED\nVersion 2.86\n\n"
"All files contained in this archive are Copyright © 1994-95 by Frank Enderle !" )
(user old_level)
; ask user where to install AudioED
(set drawer
(askdir
(prompt "Please select the directory where you would like to install "
"AudioED 2.86\nA drawer called 'AudioED' would be created !")
(help @askdir-help)
(default "SYS:")
)
)
(set @default-dest drawer)
; delete old installations
(user 1)
(if (exists (tackon drawer "AudioED") (noreq)) (
(if (askbool
(prompt "There's already an AudioED-version installed !\n\nDelete it ?\n(NOT REQUIRED FOR UPDATE!)\n")
(help @askbool-help)) (
(if (askbool
(prompt "WARNING: All files in this drawer will be deleted !\n\nContinue ?")
(help @askbool-help)) (
; we use DOS commands: Installer is very 'unfriendly' for file deletion !
(run (cat "c:delete >NIL: \"" (tackon drawer "AudioED") "\" \"" (tackon drawer "AudioED.info") "\" all"))
(run "c:delete >NIL: LOCALE:catalogs/#?/audioed.catalog")
(run "c:delete >NIL: LIBS:idx.library")
(run "c:delete >NIL: ENVARC:AudioED#?")
(run "c:delete >NIL: ENVARC:MUI/AudioED#?")
))
))
(if (NOT (askbool
(prompt "Install now AudioED ?")
(help @askbool-help))) (
(exit)
))
))
(user old_level)
(complete 20)
; install program & keyfile
(working "Installing AudioED 2.86 Program")
(copyfiles
(help @copyfiles-help)
(source "drawer_icon")
(dest drawer)
(newname "AudioED.info")
)
(set drawer (tackon drawer "AudioED"))
(makedir drawer)
(copyfiles
(help @copyfiles-help)
(source "AudioED")
(dest drawer)
(infos)
)
(if (<> (getsum "Keyfile/AudioED.key") $B81AA1DC) (
; copy keyfile to archive
(copyfiles
(help @copyfiles-help)
(source "Keyfile/AudioED.key")
(dest "ENVARC:")
)
; copy keyfile to environment
(copyfiles
(help @copyfiles-help)
(source "Keyfile/AudioED.key")
(dest "ENV:")
)
) (
(user 1)
(message "Keyfile is missing.\n\n You're running the demoversion !\n\n"
"On how to register read the documentation.")
(user old_level)
))
(complete 40)
; install library
(working "Installing required libraries")
(copylib
(help @copylib-help)
(source "libs/idx.library")
(dest "LIBS:")
)
(copylib
(help @copylib-help)
(source "libs/iff.library")
(dest "LIBS:")
)
(complete 60)
; install locales (only on > 37)
(if (> sys_ver 37) (
(working "Installing locale files")
(set language (askoptions
(choices "English" "Deutsch")
(prompt "Select language-catalogs to install")
(help @askchoices-help)
))
(set ask_language 0)
(while (< ask_language 2) (
(set language_name (select ask_language "English" "Deutsch"))
(if (BITAND language (shiftleft 1 ask_language)) (
(if (> ask_language 0) (
(copyfiles
(help @copyfiles-help)
(source (tackon (tackon "locale/catalogs" language_name) "audioed.catalog"))
(dest (tackon "LOCALE:catalogs" language_name))
)
))
))
(set ask_language (+ ask_language 1))
))
))
(complete 80)
; install documentation
(working "Installing documentation files")
(set language (askchoice
(choices "English documentation" "Deutsche Dokumentation")
(prompt "Select documentation language to install")
(help @askchoices-help)
))
(set ask_language 0)
(while (< ask_language 2) (
(set doc_name (select ask_language "docs/english/AudioED.guide" "docs/deutsch/AudioED.guide"))
(if (= language ask_language) (
(copyfiles
(help @copyfiles-help)
(source doc_name)
(dest drawer)
(infos)
)
))
(set ask_language (+ ask_language 1))
))
(working "Updating databases")
(user 1)
(if (askbool
(prompt "If you have had already installed an older\n"
"version you will have to update\n"
"the database.\n"
"(Original files are backed up)\n\n"
"Update older database ?")
(help @askbool-help)) (
(set tapes
(askdir
(prompt "Select drawer containing databases...")
(help @askdir-help)
(default drawer)
)
)
(foreach tapes "#?.idx" (
(set name (substr @each-name 0 (- (strlen @each-name) 4)))
(if (<> (substr name (- (strlen name) 4) 4) "_BAK") (
(rename
(cat (tackon tapes name) ".idx")
(cat (tackon tapes name) "_BAK.idx")
)
(rename
(cat (tackon tapes name) ".dat")
(cat (tackon tapes name) "_BAK.dat")
)
(run (cat "old2new >NIL: \"" (tackon tapes name) "_BAK\" \"" (tackon tapes name) "\" DATABASE" ))
))
))
)
)
(if (askbool
(prompt "If you're updating from version 2.5x to 2.86\n"
"your ENVARC:audioed.resident needs to be updated\n"
"(Original files are backed up)\n\n"
"Should I update audioed.resident ?")
(help @askbool-help)) (
(rename "ENV:AudioED.resident" "ENV:AudioED_BAK.resident")
(rename "ENVARC:AudioED.resident" "ENVARC:AudioED_BAK.resident")
(run "old2new >NIL: ENV:AudioED_BAK.resident ENV:AudioED.resident CONFIG")
(run "c:copy >NIL: ENV:AudioED.resident ENVARC:AudioED.resident")
)
)
(user old_level)
(complete 90)
; install programmer information
(working "Installing developer files")
(if (askbool
(help @askbool-help)
(prompt "This archive contains the catalog-description file and a "
"catalog-translation file for german.\n\nShall I install "
"them ?")) (
(copyfiles
(help @copyfiles-help)
(source "locale/developer")
(dest (tackon drawer "Developer"))
(infos)
(all)
)
)
)
(complete 100)
(exit)